Advanced Calculations

Calculate Percentage of Total

using VegaLite, DataFrames

data = DataFrame(
    Activity=["Sleeping","Eating","TV","Work","Exercise"],
    Time=[8,2,4,8,2]
)

data |>
@vlplot(
    height={step=12},
    :bar,
    transform=[
        {
            window=[{op="sum",field="Time",as="TotalTime"}],
            frame=[nothing,nothing]
        },
        {
            calculate="datum.Time/datum.TotalTime * 100",
            as="PercentOfTotal"
        }
    ],
    x={"PercentOfTotal:q", axis={title="% of total Time"}},
    y={"Activity:n"}
)

A bar graph showing what activites consume what percentage of the day.

Calculate Difference from Average

using VegaLite, VegaDatasets

dataset("movies") |>
@vlplot(
    transform=[
        {filter="datum.IMDB_Rating != null"},
        {
            joinaggregate= [{
                op=:mean,
                field=:IMDB_Rating,
                as="AverageRating"
            }]
        },
        {filter="(datum.IMDB_Rating - datum.AverageRating) > 2.5"}
    ]
) +
@vlplot(
    :bar,
    x={"IMDB_Rating:q",axis={title="IMDB Rating"}},
    y={"Title:o"}
) +
@vlplot(
    mark={
        :rule,
        color="red"
    },
    x={"AverageRating:q", aggregate="average"}
)

Calculate Difference from Annual Average

using VegaLite, VegaDatasets

dataset("movies") |>
@vlplot(
    transform=[
        {filter="datum.IMDB_Rating != null"},
        {timeUnit="year",field="Release_Date",as="year"},
        {
            joinaggregate= [{
                op=:mean,
                field=:IMDB_Rating,
                as="AverageYearRating"
            }],
            groupby=["year"]
        },
        {
            filter="(datum.IMDB_Rating - datum.AverageYearRating) > 2.5"
        }
    ]
) +
@vlplot(
    mark={:bar,clip=true},
    x={"IMDB_Rating:q",axis={title="IMDB Rating"}},
    y={"Title:o"}
) +
@vlplot(
    mark=:tick,
    color={value="red"},
    x="AverageYearRating:q",
    y="Title:o"
)

Bar graph showing the best films for the year they were produced, where best is defined by at least 2.5 points above average for that year. The red point shows the average rating for a film in that year, and the bar is the rating that the film recieved.

Calculate Residuals

using VegaLite, VegaDatasets

dataset("movies") |>
@vlplot(
    transform=[
        {filter="datum.IMDB_Rating != null"},
        {filter={timeUnit="year",field="Release_Date",range=[1900,2019]}},
        {
            joinaggregate=[{
                op="mean",
                field="IMDB_Rating",
                as="AverageRating"
            }]
        },
        {
            calculate="datum.IMDB_Rating - datum.AverageRating",
            as="RatingDelta"
        }
    ],
    :point,
    x="Release_Date:t",
    y={"RatingDelta:q", axis={title="Rating Delta"}},
    color={"RatingDelta:q",scale={domainMid=0},title="Rating Delta"}
)

A dot plot showing each movie in the database, and the difference from the average movie rating. The display is sorted by year to visualize everything in sequential order. The graph is for all Movies before 2019.

Line Charts Showing Ranks Over Time

using VegaLite, DataFrames

data = DataFrame(
    team=["Germany", "Mexico", "South Korea", "Sweden", "Germany", "Mexico",
        "South Korea", "Sweden", "Germany", "Mexico", "South Korea", "Sweden"],
    matchday=[1,1,1,1,2,2,2,2,3,3,3,3],
    point=[0,3,0,3,3,6,0,3,3,6,3,6],
    diff=[-1,1,-1,1,0,2,-2,0,-2,-1,0,3]
)

data |>
@vlplot(
    title={text="World Cup 2018: Group F Rankings"},
    transform=[{
        sort=[
            {field="point", order="descending"},
            {field="diff", order="descending"}
        ],
        window=[{
            op="rank",
            as="rank"
        }],
        groupby=["matchday"]
    }],
    mark={
        :line,
        orient="vertical"
    },
    x="matchday:o",
    y="rank:o",
    color={
        :team,
        scale={
            domain=["Germany", "Mexico", "South Korea", "Sweden"],
            range=["black", "#127153", "#C91A3C", "#0C71AB"]
        }
    }
)

Waterfall Chart of Monthly Profit and Loss

using VegaLite, DataFrames

data = DataFrame(
    label=["Begin", "Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec", "End"],
    amount=[4000,1707,-1425,-1030,1812,-1067,-1481,1228,1176,1146,1205,-1388,1492,0]
)

data |>
@vlplot(
    width=800,
    height=450,
    transform=[
        {window=[{op="sum",field="amount",as="sum"}]},
        {window=[{op="lead",field="label",as="lead"}]},
        {
            calculate="datum.lead === null ? datum.label : datum.lead",
            as="lead"
        },
        {
            calculate="datum.label === 'End' ? 0 : datum.sum - datum.amount",
            as="previous_sum"
        },
        {
            calculate="datum.label === 'End' ? datum.sum : datum.amount",
            as="amount"
        },
        {
            calculate="(datum.label !== 'Begin' && datum.label !== 'End' && datum.amount > 0 ? '+' : '') + datum.amount",
            as="text_amount"
        },
        {
            calculate="(datum.sum + datum.previous_sum) / 2",
            as="center"
        },
        {
            calculate="datum.sum < datum.previous_sum ? datum.sum : ''",
            as="sum_dec"
        },
        {
            calculate="datum.sum > datum.previous_sum ? datum.sum : ''",
            as="sum_inc"
        }
    ],
    x={"label:o",sort=nothing,axis={labelAngle=0,title="Months"}},
    config={
        text={
            fontWeight="bold",
            color="#404040"
        }
    }
) +
@vlplot(
    mark={:bar,size=45},
    y={"previous_sum:q",title="Amount"},
    y2=:sum,
    color={
        condition=[
            {test="datum.label === 'Begin' || datum.label === 'End'",value="#f7e0b6"},
            {test="datum.sum < datum.previous_sum",value="#f78a64"}
        ],
        value="#93c4aa"
    }
) +
@vlplot(
    mark={
        :rule,
        color="#404040",
        opacity=1,
        strokeWidth=2,
        xOffset=-22.5,
        x2Offset=22.5
    },
    x2=:lead,
    y="sum:q"
) +
@vlplot(
    mark={
        :text,
        dy=-4,
        baseline="bottom"
    },
    y="sum_inc:q",
    text="sum_inc:n"
) +
@vlplot(
    mark={
        :text,
        dy=4,
        baseline="top"
    },
    y="sum_dec:q",
    text="sum_dec:n"
) +
@vlplot(
    mark={
        :text,
        fontWeight="bold",
        baseline="middle"
    },
    y="center:q",
    text="text_amount:n",
    color={
        condition=[
            {test="datum.label === 'Begin' || datum.label === 'End'",value="#725a30"}
        ],
        value="white"
    }
)

Filtering Top-K Items

using VegaLite, DataFrames

data = DataFrame(
    student=["A","B","C","D","E","F","G","H","I","J","K","L","M","N","O","P","Q","R","S","T","U","V"],
    score=[100,56,88,65,45,23,66,67,13,12,50,78,66,30,97,75,24,42,76,78,21,46]
)

data |>
@vlplot(
    transform=[
        {
            window=[{ op="rank", as="rank" }],
            sort=[{ field="score", order="descending" }]
        },
        {filter="datum.rank <= 5"}
    ],
    mark=:bar,
    x="score:q",
    y={
        "student:n",
        sort={field="score",op="average",order="descending"}
    }
)

Here we use window transform to derive the total number of students along with the rank of the current student to determine the top K students and display their score.

Top-K Plot with "Others"

using VegaLite, VegaDatasets

dataset("movies") |>
@vlplot(
    title="Top Directors by Average Worldwide Gross",
    transform=[
        {
            aggregate=[{op="mean",field="Worldwide_Gross",as="aggregate_gross"}],
            groupby=["Director"]
        },
        {
            window=[{op="row_number", as="rank"}],
            sort=[{field="aggregate_gross",order="descending"}]
        },
        {
            calculate="datum.rank < 10 ? datum.Director : 'All Others'", as="ranked_director"
        }
    ],
    :bar,
    x={aggregate="mean","aggregate_gross:q",title=nothing},
    y={
        sort={op="mean",field="aggregate_gross",order="descending"},
        "ranked_director:o",
        title=nothing
    }
)

Top-K plot with \"others\" by Trevor Manz, adapted from https://observablehq.com/@manzt/top-k-plot-with-others-vega-lite-example.

Using the lookup transform to combine data

using VegaLite, VegaDatasets

dataset("lookup_groups") |>
@vlplot(
    transform=[
        {
            lookup="person",
            from={
                data=dataset("lookup_people"),
                key="name",
                fields=["age","height"]
            }
        }
    ],
    :bar,
    x="group:o",
    y={"age:q",aggregate="mean"}
)

Cumulative Frequency Distribution

using VegaLite, VegaDatasets

dataset("movies") |>
@vlplot(
    :area,
    transform=[{
        sort=[{field=:IMDB_Rating}],
        window=[{field=:count,op="count",as="cumulative_count"}],
        frame=[nothing,0]
    }],
    x="IMDB_Rating:q",
    y="cumulative_count:q"
)

Layered Histogram and Cumulative Histogram

using VegaLite, VegaDatasets

dataset("movies") |>
@vlplot(
    transform=[
        {bin=true,field=:IMDB_Rating,as="bin_IMDB_Rating"},
        {
            aggregate=[{op=:count,as="count"}],
            groupby=["bin_IMDB_Rating", "bin_IMDB_Rating_end"]
        },
        {filter="datum.bin_IMDB_Rating !== null"},
        {
            sort=[{field=:bin_IMDB_Rating}],
            window=[{field=:count,op="sum",as="cumulative_count"}],
            frame=[nothing,0]
        }
    ],
    x={"bin_IMDB_Rating:q",scale={zero=false},title="IMDB Rating"},
    x2=:bin_IMDB_Rating_end
) +
@vlplot(
    :bar,
    y="cumulative_count:q"
) +
@vlplot(
    mark={:bar,color=:yellow,opacity=0.5},
    y="count:q"
)

Parallel Coordinate Plot

using VegaLite, VegaDatasets

dataset("iris") |>
@vlplot(
    width=600,
    height=300,
    config={
        axisX={domain=false, labelAngle=0, tickColor="#ccc", "title"=nothing},
        view={stroke=nothing},
        style={
            label={baseline="middle", align="right", dx=-5},
            tick={orient="horizontal"}
        }
    },
    transform=[
        { window=[{op="count", as="index" }] },
        {fold=["petalLength", "petalWidth", "sepalLength", "sepalWidth"]},
        {
            joinaggregate=[
                {op="min",field="value",as="min"},
                {op="max",field="value",as="max"}
            ],
            groupby=["key"]
        },
        {
            calculate="(datum.value - datum.min) / (datum.max-datum.min)",
            as="norm_val"
        },
        {
            calculate="(datum.min + datum.max) / 2",
            as="mid"
        },
        {
            calculate="'petalLength: '+datum.petalLength+', '+'petalWidth: '+datum.petalWidth+', sepalLength: '+datum.sepalLength+', '+'sepalWidth: '+datum.sepalWidth",
            as="tt"
        } #How to add a line break?
    ]
) +
@vlplot(
    mark={:rule,color="#ccc"},
    detail={aggregate="count",type="quantitative"},
    x="key:n"
) +
@vlplot(
    mark=:line,
    color={field="species",type="nominal"},
    detail={field="index",type="nominal"},
    opacity={value=0.3},
    x="key:n",
    y={"norm_val:q",axis=nothing},
    tooltip={"tt:n"}
)  +
@vlplot(
    mark={:text,style="label"},
    text={aggregate="max",field="max",type="quantitative"},
    x="key:n",
    y={value=0}
)  +
@vlplot(
    mark={:tick,style="tick",size=8,color="#ccc"},
    x="key:n",
    y={value=0}
)  +
@vlplot(
    mark={:text,style="label"},
    text={aggregate="min",field="mid",type="quantitative"},
    x="key:n",
    y={value=150}
)  +
@vlplot(
    mark={:tick,style="tick",size=8,color="#ccc"},
    x="key:n",
    y={value=150}
)  +
@vlplot(
    mark={:text,style="label"},
    text={aggregate="min",field="min",type="quantitative"},
    x="key:n",
    y={value=300}
)  +
@vlplot(
    mark={:tick,style="tick",size=8,color="#ccc"},
    x="key:n",
    y={value=300}
)

Though Vega-Lite supports only one scale per axes, one can create a parallel coordinate plot by folding variables, using joinaggregate to normalize their values and using ticks and rules to manually create axes.

Bar Chart Showing Argmax Value

using VegaLite, VegaDatasets

dataset("movies") |>
@vlplot(
    mark=:bar,
    x={aggregate={argmax="US_Gross"},"Production_Budget:q"},
    y={"Major_Genre:n"}
)

The production budget of the movie that has the highest US Gross in each major genre.

Layering Averages over Raw Values

using VegaLite, VegaDatasets

dataset("stocks") |>
@vlplot(
    transform=[{filter="datum.symbol==='GOOG'"}]
) +
@vlplot(
    mark={:point,opacity=0.3},
    x={timeUnit="year","date:t"},
    y="price:q"
) +
@vlplot(
    mark=:line,
    x={timeUnit="year","date:t"},
    y={aggregate="mean","price:q"}
)

Plot showing average data with raw values in the background.

Layering Rolling Averages over Raw Values

using VegaLite, VegaDatasets

dataset("seattle-weather") |>
@vlplot(
    width=400,
    height=300,
    transform=[{
        frame=[-15,15],
        window=[{field="temp_max",op="mean",as="rolling_mean"}]
    }]
) +
@vlplot(
    mark={:point,opacity=0.3},
    x={"date:t",title="Date"},
    y={"temp_max:q",title="Max Temperature"}
) +
@vlplot(
    mark={:line,size=3,color="red"},
    x={"date:t",title="Date"},
    y={"rolling_mean:q"}
)